A documentation string is written using the Lisp syntax for strings, with double-quote characters surrounding the text. It is, in fact, an actual Lisp string. When the string appears in the proper place in a function or variable definition, it serves as the function's or variable's documentation. In a function definition (a lambda or defun form), the documentation string is specified after the argument list, and is normally stored directly in the function object. Function Documentation. You can also put function documentation in the function-documentation property of a function name (Accessing Documentation). In a variable definition (a defvar form), the documentation string is specified after the initial value. Defining Variables. The string is stored in the variable's variable-documentation property. Sometimes, Emacs does not keep documentation strings in memory. There are two such circumstances. Firstly, to save memory, the documentation for preloaded functions and variables (including primitives) is kept in a file named DOC, in the directory specified by doc-directory (Accessing Documentation). Secondly, when a function or variable is loaded from a byte-compiled file, Emacs avoids loading its documentation string (Docs and Compilation). In both cases, Emacs looks up the documentation string from the file only when needed, such as when the user calls C-h f (describe-function) for a function. Documentation strings can contain special key substitution sequences, referring to key bindings which are looked up only when the user views the documentation. This allows the help commands to display the correct keys even if a user rearranges the default key bindings. Keys in Documentation. In the documentation string of an autoloaded command (Autoload), these key-substitution sequences have an additional special effect: they cause C-h f on the command to trigger autoloading. (This is needed for correctly setting up the hyperlinks in the *Help* buffer.)

documentation-property

This function returns the documentation string recorded in symbol's property list under property property. It is most often used to look up the documentation strings of variables, for which property is variable-documentation. However, it can also be used to look up other kinds of documentation, such as for customization groups (but for function documentation, use the documentation function, below). If the property value refers to a documentation string stored in the DOC file or a byte-compiled file, this function looks up that string and returns it. If the property value isn't nil, isn't a string, and doesn't refer to text in a file, then it is evaluated as a Lisp expression to obtain a string. Finally, this function passes the string through substitute-command-keys to substitute key bindings (Keys in Documentation). It skips this step if verbatim is non-nil.

(documentation-property 'command-line-processed
   'variable-documentation)
     => "Non-nil once command line has been processed"
(symbol-plist 'command-line-processed)
     => (variable-documentation 188902)
(documentation-property 'emacs 'group-documentation)
     => "Customization of the One True Editor."

documentation

This function returns the documentation string of function. It handles macros, named keyboard macros, and special forms, as well as ordinary functions. If function is a symbol, this function first looks for the function-documentation property of that symbol; if that has a non-nil value, the documentation comes from that value (if the value is not a string, it is evaluated). If function is not a symbol, or if it has no function-documentation property, then documentation extracts the documentation string from the actual function definition, reading it from a file if called for. Finally, unless verbatim is non-nil, this function calls substitute-command-keys. The result is the documentation string to return. The documentation function signals a void-function error if function has no function definition. However, it is OK if the function definition has no documentation string. In that case, documentation returns nil.

face-documentation

This function returns the documentation string of face as a face.

Here is an example of using the two functions, documentation and documentation-property, to display the documentation strings for several symbols in a *Help* buffer.

(defun describe-symbols (pattern)
  "Describe the Emacs Lisp symbols matching PATTERN.
All symbols that have PATTERN in their name are described
in the *Help* buffer."
  (interactive "sDescribe symbols matching: ")
  (let ((describe-func
         (lambda (s)
           ;; Print description of symbol.
           (if (fboundp s)             ; It is a function.
               (princ
                (format "%s\t%s\n%s\n\n" s
                  (if (commandp s)
                      (let ((keys (where-is-internal s)))
                        (if keys
                            (concat
                             "Keys: "
                             (mapconcat 'key-description
                                        keys " "))
                          "Keys: none"))
                    "Function")
                  (or (documentation s)
                      "not documented"))))

           (if (boundp s)              ; It is a variable.
               (princ
                (format "%s\t%s\n%s\n\n" s
                  (if (custom-variable-p s)
                      "Option " "Variable")
                  (or (documentation-property
                        s 'variable-documentation)
                      "not documented"))))))
        sym-list)

    ;; Build a list of symbols that match pattern.
    (mapatoms (lambda (sym)
                (if (string-match pattern (symbol-name sym))
                    (setq sym-list (cons sym sym-list)))))

    ;; Display the data.
    (help-setup-xref (list 'describe-symbols pattern)
                 (called-interactively-p 'interactive))
    (with-help-window (help-buffer)
      (mapcar describe-func (sort sym-list 'string<)))))

The describe-symbols function works like apropos, but provides more information.

(describe-symbols "goal")

---------- Buffer: *Help* ----------
goal-column     Option
Semipermanent goal column for vertical motion, as set by ...
@c Do not blithely break or fill these lines.
@c That makes them incorrect.

minibuffer-temporary-goal-position      Variable
not documented

set-goal-column Keys: C-x C-n
Set the current horizontal position as a goal for C-n and C-p.
@c DO NOT put a blank line here!  That is factually inaccurate!
Those commands will move to this position in the line moved to
rather than trying to keep the same horizontal position.
With a non-nil argument ARG, clears out the goal column
so that C-n and C-p resume vertical motion.
The goal column is stored in the variable ‘goal-column’.

(fn ARG)

temporary-goal-column   Variable
Current goal column for vertical motion.
It is the column where point was at the start of the current run
of vertical motion commands.

When moving by visual lines via the function ‘line-move-visual’, it is a cons
cell (COL . HSCROLL), where COL is the x-position, in pixels,
divided by the default column width, and HSCROLL is the number of
columns by which window is scrolled from left margin.

When the ‘track-eol’ feature is doing its job, the value is
‘most-positive-fixnum’.
---------- Buffer: *Help* ----------

Snarf-documentation

This function is used when building Emacs, just before the runnable Emacs is dumped. It finds the positions of the documentation strings stored in the file filename, and records those positions into memory in the function definitions and variable property lists. Building Emacs. Emacs reads the file filename from the emacs/etc directory. When the dumped Emacs is later executed, the same file will be looked for in the directory doc-directory. Usually filename is "DOC".

doc-directory

This variable holds the name of the directory which should contain the file "DOC" that contains documentation strings for built-in and preloaded functions and variables. In most cases, this is the same as data-directory. They may be different when you run Emacs from the directory where you built it, without actually installing it. Definition of data-directory.

When documentation strings refer to key sequences, they should use the current, actual key bindings. They can do so using certain special text sequences described below. Accessing documentation strings in the usual way substitutes current key binding information for these special sequences. This works by calling substitute-command-keys. You can also call that function yourself. Here is a list of the special sequences and what they mean:

\[COMMAND]

stands for a key sequence that will invoke command, or M-x /command/ if command has no key bindings.

\{MAPVAR}

stands for a summary of the keymap which is the value of the variable mapvar. The summary is made using describe-bindings.

\<MAPVAR>

stands for no text itself. It is used only for a side effect: it specifies mapvar's value as the keymap for any following \[COMMAND] sequences in this documentation string.

`

(grave accent) stands for a left quote. This generates a left single quotation mark, an apostrophe, or a grave accent depending on the value of text-quoting-style. Text Quoting Style.

'

(apostrophe) stands for a right quote. This generates a right single quotation mark or an apostrophe depending on the value of text-quoting-style.

\=

quotes the following character and is discarded; thus, \=` puts ` into the output, \\[= puts \[ into the output, and \\== puts \= into the output.

Please note: Each \ must be doubled when written in a string in Emacs Lisp.

text-quoting-style

The value of this variable is a symbol that specifies the style Emacs should use for single quotes in the wording of help and messages. If the variable's value is curve, the style is ‘like this’ with curved single quotes. If the value is straight, the style is 'like this' with straight apostrophes. If the value is grave, quotes are not translated and the style is `like this' with grave accent and apostrophe, the standard style before Emacs version 25. The default value nil acts like curve if curved single quotes seem to be displayable, and like grave otherwise. This option is useful on platforms that have problems with curved quotes. You can customize it freely according to your personal preference.

substitute-command-keys

This function scans string for the above special sequences and replaces them by what they stand for, returning the result as a string. This permits display of documentation that refers accurately to the user's own customized key bindings. By default, the key bindings are given a special face help-key-binding, but if the optional argument no-face is non-nil, the function doesn't add this face to the produced string. If a command has multiple bindings, this function normally uses the first one it finds. You can specify one particular key binding by assigning an :advertised-binding symbol property to the command, like this:

(put 'undo :advertised-binding [?\C-/])

The :advertised-binding property also affects the binding shown in menu items (Menu Bar). The property is ignored if it specifies a key binding that the command does not actually have. Here are examples of the special sequences:

(substitute-command-keys
   "To abort recursive edit, type `\\[abort-recursive-edit]'.")
=> "To abort recursive edit, type ‘C-]’."

(substitute-command-keys
   "The keys that are defined for the minibuffer here are:
  \\{minibuffer-local-must-match-map}")
=> "The keys that are defined for the minibuffer here are:

?               minibuffer-completion-help
SPC             minibuffer-complete-word
TAB             minibuffer-complete
C-j             minibuffer-complete-and-exit
RET             minibuffer-complete-and-exit
C-g             abort-recursive-edit
"

(substitute-command-keys
   "To abort a recursive edit from the minibuffer, type \
`\\<minibuffer-local-must-match-map>\\[abort-recursive-edit]'.")
=> "To abort a recursive edit from the minibuffer, type ‘C-g’."

There are other special conventions for the text in documentation strings—for instance, you can refer to functions, variables, and sections of this manual. Documentation Tips, for details.

Typically, grave accents and apostrophes are treated specially in documentation strings and diagnostic messages, and translate to matching single quotation marks (also called "curved quotes"). For example, the documentation string "Alias for `foo'." and the function call (message "Alias for `foo'.") both translate to "Alias for ‘foo’.". Less commonly, Emacs displays grave accents and apostrophes as themselves, or as apostrophes only (e.g., "Alias for 'foo'."). Documentation strings and message formats should be written so that they display well with any of these styles. For example, the documentation string "Alias for 'foo'." is probably not what you want, as it can display as "Alias for ’foo’.", an unusual style in English. Sometimes you may need to display a grave accent or apostrophe without translation, regardless of text quoting style. In a documentation string, you can do this with escapes. For example, in the documentation string "\\=`(a the grave accent is intended to denote Lisp code, so it is escaped and displays as itself regardless of quoting style. In a call to message or error, you can avoid translation by using a format "%s" with an argument that is a call to format. For example, (message "%s" (format "`(a displays a message that starts with grave accent regardless of text quoting style.

text-quoting-style

The value of this user option is a symbol that specifies the style Emacs should use for single quotes in the wording of help and messages. If the option's value is curve, the style is ‘like this’ with curved single quotes. If the value is straight, the style is 'like this' with straight apostrophes. If the value is grave, quotes are not translated and the style is `like this' with grave accent and apostrophe, the standard style before Emacs version 25. The default value nil acts like curve if curved single quotes seem to be displayable, and like grave otherwise. This option is useful on platforms that have problems with curved quotes. You can customize it freely according to your personal preference.

These functions convert events, key sequences, or characters to textual descriptions. These descriptions are useful for including arbitrary text characters or key sequences in messages, because they convert non-printing and whitespace characters to sequences of printing characters. The description of a non-whitespace printing character is the character itself.

key-description

This function returns a string containing the Emacs standard notation for the input events in sequence. If prefix is non-nil, it is a sequence of input events leading up to sequence and is included in the return value. Both arguments may be strings, vectors or lists. Input Events, for more information about valid events.

(key-description [?\M-3 delete])
     => "M-3 <delete>"
(key-description [delete] "\M-3")
     => "M-3 <delete>"

See also the examples for single-key-description, below.

single-key-description

This function returns a string describing event in the standard Emacs notation for keyboard input. A normal printing character appears as itself, but a control character turns into a string starting with C-, a meta character turns into a string starting with M-, and space, tab, etc., appear as SPC, TAB, etc. A function key symbol appears inside angle brackets <...>. An event that is a list appears as the name of the symbol in the CAR of the list, inside angle brackets. If the optional argument no-angles is non-nil, the angle brackets around function keys and event symbols are omitted; this is for compatibility with old versions of Emacs which didn't use the brackets.

(single-key-description ?\C-x)
     => "C-x"
(key-description "\C-x \M-y \n \t \r \f123")
     => "C-x SPC M-y SPC C-j SPC TAB SPC RET SPC C-l 1 2 3"
(single-key-description 'delete)
     => "<delete>"
(single-key-description 'C-mouse-1)
     => "C-<mouse-1>"
(single-key-description 'C-mouse-1 t)
     => "C-mouse-1"

text-char-description

This function returns a string describing character in the standard Emacs notation for characters that can appear in text—similar to single-key-description, except that the argument must be a valid character code that passes a characterp test (Character Codes). The function produces descriptions of control characters with a leading caret (which is how Emacs usually displays control characters in buffers). Characters with modifier bits will cause this function to signal an error (ASCII characters with the Control modifier are an exception, they are represented as control characters).

(text-char-description ?\C-c)
     => "^C"
(text-char-description ?\M-m)
     error--> Wrong type argument: characterp, 134217837

Command read-kbd-macro

This function is used mainly for operating on keyboard macros, but it can also be used as a rough inverse for key-description. You call it with a string containing key descriptions, separated by spaces; it returns a string or vector containing the corresponding events. (This may or may not be a single valid key sequence, depending on what events you use; Key Sequences.) If need-vector is non-nil, the return value is always a vector.

Emacs provides a variety of built-in help functions, all accessible to the user as subcommands of the prefix C-h. For more information about them, see Help. Here we describe some program-level interfaces to the same information.

Command apropos

This function finds all meaningful symbols whose names contain a match for the apropos pattern pattern. An apropos pattern is either a word to match, a space-separated list of words of which at least two must match, or a regular expression (if any special regular expression characters occur). A symbol is meaningful if it has a definition as a function, variable, or face, or has properties. The function returns a list of elements that look like this:

(SYMBOL SCORE FUNCTION-DOC VARIABLE-DOC
 PLIST-DOC WIDGET-DOC FACE-DOC GROUP-DOC)

Here, score is an integer measure of how important the symbol seems to be as a match. Each of the remaining elements is a documentation string, or nil, for symbol as a function, variable, etc. It also displays the symbols in a buffer named *Apropos*, each with a one-line description taken from the beginning of its documentation string. If do-all is non-nil, or if the user option apropos-do-all is non-nil, then apropos also shows key bindings for the functions that are found; it also shows all interned symbols, not just meaningful ones (and it lists them in the return value as well).

help-map

The value of this variable is a local keymap for characters following the Help key, C-h.

{Prefix Command}

This symbol is not a function; its function definition cell holds the keymap known as help-map. It is defined in help.el as follows:

(define-key global-map (string help-char) 'help-command)
(fset 'help-command help-map)

help-char

The value of this variable is the help character—the character that Emacs recognizes as meaning Help. By default, its value is 8, which stands for C-h. When Emacs reads this character, if help-form is a non-nil Lisp expression, it evaluates that expression, and displays the result in a window if it is a string. Usually the value of help-form is nil. Then the help character has no special meaning at the level of command input, and it becomes part of a key sequence in the normal way. The standard key binding of C-h is a prefix key for several general-purpose help features. The help character is special after prefix keys, too. If it has no binding as a subcommand of the prefix key, it runs describe-prefix-bindings, which displays a list of all the subcommands of the prefix key.

help-event-list

The value of this variable is a list of event types that serve as alternative help characters. These events are handled just like the event specified by help-char.

help-form

If this variable is non-nil, its value is a form to evaluate whenever the character help-char is read. If evaluating the form produces a string, that string is displayed. A command that calls read-event, read-char-choice, read-char, read-char-from-minibuffer, or y-or-n-p probably should bind help-form to a non-nil expression while it does input. (The time when you should not do this is when C-h has some other meaning.) Evaluating this expression should result in a string that explains what the input is for and how to enter it properly. Entry to the minibuffer binds this variable to the value of minibuffer-help-form (Definition of minibuffer-help-form).

prefix-help-command

This variable holds a function to print help for a prefix key. The function is called when the user types a prefix key followed by the help character, and the help character has no binding after that prefix. The variable's default value is describe-prefix-bindings.

Command describe-prefix-bindings

This function calls describe-bindings to display a list of all the subcommands of the prefix key of the most recent key sequence. The prefix described consists of all but the last event of that key sequence. (The last event is, presumably, the help character.)

The following two functions are meant for modes that want to provide help without relinquishing control, such as the electric modes. Their names begin with Helper to distinguish them from the ordinary help functions.

Command Helper-describe-bindings

This command pops up a window displaying a help buffer containing a listing of all of the key bindings from both the local and global keymaps. It works by calling describe-bindings.

Command Helper-help

This command provides help for the current mode. It prompts the user in the minibuffer with the message Help (Type ? for further options), and then provides assistance in finding out what the key bindings are, and what the mode is intended for. It returns nil. This can be customized by changing the map Helper-help-map.

data-directory

This variable holds the name of the directory in which Emacs finds certain documentation and text files that come with Emacs.

help-buffer

This function returns the name of the help buffer, which is normally *Help*; if such a buffer does not exist, it is first created.

with-help-window

This macro evaluates body like with-output-to-temp-buffer (Temporary Displays), inserting any output produced by its forms into a buffer specified by buffer-or-name, which can be a buffer or the name of a buffer. (Frequently, buffer-or-name is the value returned by the function help-buffer.) This macro puts the specified buffer into Help mode and displays a message telling the user how to quit and scroll the help window. It selects the help window if the current value of the user option help-window-select has been set accordingly. It returns the last value in body.

help-setup-xref

This function updates the cross reference data in the *Help* buffer, which is used to regenerate the help information when the user clicks on the Back or Forward buttons. Most commands that use the *Help* buffer should invoke this function before clearing the buffer. The item argument should have the form (FUNCTION . ARGS), where function is a function to call, with argument list args, to regenerate the help buffer. The interactive-p argument is non-nil if the calling command was invoked interactively; in that case, the stack of items for the *Help* buffer's Back buttons is cleared.

describe-symbols example, for an example of using help-buffer, with-help-window, and help-setup-xref.

make-help-screen

This macro defines a help command named fname that acts like a prefix key that shows a list of the subcommands it offers. When invoked, fname displays help-text in a window, then reads and executes a key sequence according to help-map. The string help-text should describe the bindings available in help-map. The command fname is defined to handle a few events itself, by scrolling the display of help-text. When fname reads one of those special events, it does the scrolling and then reads another event. When it reads an event that is not one of those few, and which has a binding in help-map, it executes that key's binding and then returns. The argument help-line should be a single-line summary of the alternatives in help-map. In the current version of Emacs, this argument is used only if you set the option three-step-help to t. This macro is used in the command help-for-help which is the binding of C-h C-h.

three-step-help

If this variable is non-nil, commands defined with make-help-screen display their help-line strings in the echo area at first, and display the longer help-text strings only if the user types the help character again.

Emacs can list functions based on various groupings. For instance, string-trim and mapconcat are "string" functions, so M-x shortdoc-display-group RET string RET will give an overview of functions that operate on strings. The documentation groups are created with the define-short-documentation-group macro.

define-short-documentation-group

Define group as a group of functions, and provide short summaries of using those functions. The optional argument functions is a list whose elements are of the form:

(FUNC [KEYWORD VAL]...)

The following keywords are recognized:

:eval

The value should be a form that has no side effect when evaluated. The form will be used in the documentation by printing it with prin1 (Output Functions). However, if the form is a string, it will be inserted as-is, and the string will then be read to yield the form. In any case, the form will then be evaluated, and the result used. For instance: :eval (concat "foo" "bar" "zot") :eval "(make-string 5 ?x)" will result in: (concat "foo" "bar" "zot") > "foobarzot" (make-string 5 ?x) => "xxxxx" (The reason for allowing both Lisp forms and strings here is so that printing could be controlled in the few cases where a certain presentation of the form is wished for. In the example, =?x would otherwise have been printed as 120 if it hadn't been included in a string.)

:no-eval

This is like :eval, except that the form will not be evaluated. In these cases, a :result element of some kind (see below) should be included. :no-eval (file-symlink-p "/tmp/foo") :eg-result t

:no-eval*

Like :no-eval, but always inserts [it depends] as the result. For instance: :no-eval* (buffer-string) will result in: (buffer-string) [click] [it depends]

:no-value

Like :no-eval, but is used when the function in question has no well-defined return value, and is used for side effect only.

:result

Used to output the result from non-evaluating example forms. :no-eval (setcar list 'c) :result c

:eg-result

Used to output an example result from non-evaluating example forms. For instance: :no-eval (looking-at "f[0-9]") :eg-result t will result in: (looking-at "f[0-9]") eg. [click] t

:result-string, :eg-result-string

These two are the same as :result and :eg-result, respectively, but are inserted as is. This is useful when the result is unreadable or should be of a particular form: :no-eval (find-file "/tmp/foo") :eg-result-string "#<buffer foo>" :no-eval (default-file-modes) :eg-result-string "#o755"

:no-manual

Indicates that this function is not documented in the manual.

:args

By default, the function's actual argument list is shown. If :args is present, they are used instead. :args (regexp string)

Here's a very short example:

(define-short-documentation-group string
  "Creating Strings"
  (substring
   :eval (substring "foobar" 0 3)
   :eval (substring "foobar" 3))
  (concat
   :eval (concat "foo" "bar" "zot")))

The first argument is the name of the group to be defined, and then follows any number of function descriptions. A function can belong to any number of documentation groups. In addition to function descriptions, the list can also have string elements, which are used to divide a documentation group into sections.

shortdoc-add-function

Lisp packages can add functions to groups with this command. Each elem should be a function description, as described above. group is the function group, and section is what section in the function group to insert the function into. If group doesn't exist, it will be created. If section doesn't exist, it will be added to the end of the function group.